100 '赤道座標→天文地平座標変換プログラム
110 '南を方位０度として西回り（西は方位角90度）
120 'シャープポケコンE-200用（他の機種でも若干の修正で利用可能）
130 '姫路近郊で使用する（東経１３５度、北緯３５度）
140 'P=135及びQ=35の値を変更すれば他の地域でも使える
150 '------------------------------------------------------------
160 CLS :CLEAR : DIM Z(10)
170 PRINT "< RA.DC => A.H >"
180 PRINT "(S=0/W=90/N=180)
190 INPUT "YEAR  =";Y
200 INPUT "MOUNTH=";Z(4)
210 INPUT "DAY   =";N
220 T= INT ((Y-1901)*365.25+.1)
230 '
240 DATA 0,31,59,90,120,151,181,212,243,273,304,334
250 RESTORE 240
260 FOR I=1 TO Z(4)
270    READ R
280 NEXT I
290 '
300 Z(6)=Y-1900
310 IF INT (Y/4)*4<>Z(6) THEN 330
320 IF Z(4)>=3 THEN R=R+1
330 Z(3)=T+R+N
340 PRINT "Time-H=";:INPUT J
350 PRINT "Time-M=";:INPUT O
360 Y=(Z(3)+(J+O/60)/24-36160.5)/36525
370 '-----------------------------------天体の赤経[RA]・赤緯[DC]を入力
380 PRINT "RA=";:INPUT U
390 PRINT "DC=";:INPUT K
400 ' ﾄｳｹｲ ､ﾎｸｲ
410 P=135 :Q=35  　　　　'--------------この値は明石市の場合
420 Z(5)=(J+O/60)-9
430 Z(2)=2400.0513*Y+6.69736+Z(5)
440 Z(2)=Z(2)+2400
450 Z=Z(2)- INT (Z(2)/24)*24
460 H=(Z*15+P-U*15)
470 W= SIN H : G= COS H
480 V= SIN K : F= COS K
490 X= SIN Q : M= COS Q
500 A=-F*W
510 B=V*M-F*X*G
520 C=V*X+F*M*G
530 D= ATN (C/ SQR (A^2+B^2))
540 E= ATN (A/B)
550 IF B<0 THEN E=E+180
560 IF E<0 THEN E=E+360
570 PRINT "ﾎｳｲ [A]=";
580 E=E+180
590 IF E>360 THEN  E=E-360
600 AA=E :GOSUB *DSP
610 PRINT "ｺｳﾄﾞ[H]=";
620 AA=D :GOSUB *DSP
630 ZZ$=INKEY$:IF ZZ$="" THEN 630
640 GOTO 340
650 '
660 *DSP
670 HH$=""
680 AA$= STR$ ( DMS AA)
690 FOR II=1 TO 3
700   A1$= MID$ (AA$,II,1)
710   IF A1$="." THEN 740
720   HH$=HH$+A1$
730 NEXT II
740 '
750 MM$= MID$ (AA$,II+1,2)
760 PRINT HH$;"ﾟ ";MM$;"'"
770 RETURN

※備考：赤経・赤緯の入力は下記のようにDEGを使う。
　　α3h45mなら　DEG3.45とキーインする・・このようにすれば
　　ポケコンの中で10進数の3.75に変換されて入力される。